[指标]通达信布林波段掘金主图

摘要： 　　这个主图指标是基于布林线(Bollinger Bands)进行扩展分析，并结合了一些其他技术条件来给出交易信号。代码如下：MID:MA(CLOSE,21),COLORWHI...

　　这个主图指标是基于布林线(Bollinger Bands)进行扩展分析，并结合了一些其他技术条件来给出交易信号。

代码如下：

MID:MA(CLOSE,21),COLORWHITE;

UPPER:MID + 1.96*STD(CLOSE,21),COLORYELLOW;

LOWER:MID - 1.96*STD(CLOSE,21),COLORYELLOW;

UP:MID + 2.58*STD(CLOSE,21),COLORFF00FF;

LOOW:MID - 2.58*STD(CLOSE,21),COLORFF00FF;

单边上升:=(C>MID);

单边下降:=(C< MID);

布林线开口:=UP-LOOW;

多头行情:=C>MA(C,5) AND MA(C,5)>MA(C,10);

股价在高位:=((C-LLV(C,30))/(HHV(C,30)-LLV(C,30))>0.6);

股价在低位:=((C-LLV(C,30))/(HHV(C,30)-LLV(C,30))< 0.4);

布林线缩口:=((UPPER-MID)/MID< 0.05);

STICKLINE(单边上升,MID,UP,6,0),COLOR330066;

STICKLINE(单边下降,LOOW,MID,6,0),COLOR545454;

DRAWTEXT(布林线缩口,MID,'▲'),COLORWHITE;

STICKLINE((OPEN >= CLOSE),OPEN,CLOSE,3,0),COLORCYAN;

STICKLINE((OPEN >= CLOSE),HIGH,LOW,0,0),COLORCYAN;

STICKLINE((OPEN < CLOSE),OPEN,CLOSE,3,0),COLORRED;

STICKLINE((OPEN < CLOSE),HIGH,LOW,0,0),COLORRED;

MID,COLORWHITE;

UPPER,COLORYELLOW;

LOWER,COLORYELLOW;

UP,COLORFF00FF;

LOOW,COLORFF00FF;

DRAWTEXT(单边上升 AND REF(C,1)>REF(UP,1) AND C < UP ,UP*1.08,'减仓'),COLOR00FF00;

DRAWTEXT(REF(布林线开口,1)=HHV(布林线开口,20) AND 单边上升,UP*1.08,'卖出'),COLORWHITE;

空仓:=(CROSS(MID,AMOUNT/V/100));

DRAWTEXT(空仓,UP*1.05,'空仓'),COLORYELLOW;

DRAWTEXT(BARSLAST(布林线缩口)=1 AND C< MA(C,10),UP*1.08,'一轮跌势起'),COLOR00FF00;

适当建仓:=(单边上升 AND FILTER(多头行情,20) AND V>MA(V,3));

DRAWTEXT(适当建仓,LOOW,'适当建仓'),COLORRED;

加仓:=(单边上升 AND REF(C-MID,1)=LLV(C-MID,5));

DRAWTEXT(加仓 AND BARSLAST(适当建仓)< BARSLAST(空仓),LOOW,'加仓'),COLORFF00FF;

一波行情起:=(BARSLAST(布林线缩口)<=3 AND V>MA(V,3) AND 股价在低位 AND C>REF(C,1) AND C>MA(C,10));

DRAWTEXT(FILTER(一波行情起,5),LOWER,'一波行情起'),COLORRED;

一波跌势完:=(单边下降 AND BARSLAST(REF(布林线开口,1)=HHV(布林线开口,50))<=5 AND LOOW>REF(LOOW,1) AND C < MID) AND 股价在低位;

DRAWTEXT(FILTER(一波跌势完,5),LOWER,'抢反弹');

　　这段代码首先定义了一系列变量：

　　MID是 21 日收盘价的移动平均线，颜色为白色。

　　UPPER是中轨线MID加上 1.96 倍的 21 日收盘价标准差，颜色为黄色。

　　LOWER是中轨线MID减去 1.96 倍的 21 日收盘价标准差，颜色为黄色。

　　UP是中轨线MID加上 2.58 倍的 21 日收盘价标准差，颜色为粉色。

　　LOOW是中轨线MID减去 2.58 倍的 21 日收盘价标准差，颜色为粉色。

　　接着定义了一些交易条件：

　　单边上升和单边下降分别根据当前股价与中轨线MID的大小关系判断。

　　布林线开口是上轨UP减去下轨LOOW。

　　多头行情是当前股价大于 5 日均线且 5 日均线大于 10 日均线。

　　股价在高位和股价在低位是通过当前股价与一段时间内的最低价和最高价的相对位置判断。

　　布林线缩口是上轨与中轨之差相对于中轨小于一定比例。

　　然后使用不同的颜色绘制不同条件下的价格走势线条，并在特定条件下显示文字提示，如 “减仓”“卖出”“空仓”“适当建仓”“加仓”“一波行情起”“抢反弹” 等，为投资者提供交易决策参考。